# include common project settings
!include( ../common.pri ) {
    error( "Couldn't find the common.pri file!" )
}

QT       += core-private multimedia-private gui widgets printsupport opengl

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000 \
           QCUSTOMPLOT_USE_OPENGL

#           AUDIO_DECODER

SOURCES += \
    ConstrainedSpinBox.cpp \
    CustomAudioDevice.cpp \
    LogItemDelegate.cpp \
    MainWindow.cpp \
    QWAMDelegate.cpp \
    RtcpWorker.cpp \
    RtpWorker.cpp \
    SinkDevice.cpp \
    SourceDevice.cpp \
    main.cpp \
    qcustomplot.cpp \
    SettingsDialog.cpp

HEADERS += \
    AITStructs.h \
    AppSettings.h \
    ConstrainedSpinBox.h \
    CustomAudioDevice.h \
    FormatHelpers.h \
    LogItemDelegate.h \
    MainWindow.h \
    QWAMDelegate.h \
    RtcpWorker.h \
    RtpWorker.h \
    SinkDevice.h \
    SourceDevice.h \
    UICommon.h \
    qcustomplot.h \
    SettingsDialog.h

FORMS += \
    MainWindow.ui \
    SettingsDialog.ui

# added support for light and dark themes
RESOURCES += \
    afdx.qrc

win32 {
    # tweak the defines to ensure that we can build with warning level 4
    DEFINES += _WIN32_WINNT=0x0601 WIN32_LEAN_AND_MEAN
	# Simple-FFT library requires square brackets for element access
	DEFINES += __USE_SQUARE_BRACKETS_FOR_ELEMENT_ACCESS_OPERATOR

    # Add library to support htonl, htons, ntohl, ntohs
    QMAKE_LIBS += ws2_32.lib

    CONFIG(debug, debug|release) {
        LIBS += -lfmtd
        LIBS += -L$$OUT_PWD/../util/debug/ -lutil 
        LIBS += -L$${VCPKG}/installed/x64-windows/debug/lib
        PRE_TARGETDEPS += $$OUT_PWD/../util/debug/util.lib
    } else {
        LIBS += -lfmt
        LIBS += -L$$OUT_PWD/../util/release/ -lutil
        LIBS += -L$${VCPKG}/installed/x64-windows/lib
        PRE_TARGETDEPS += $$OUT_PWD/../util/release/util.lib
    }

    LIBS += \
        -L$${EXTLIBS}/ait664/lib \
        -la664_api \
        -lOpenGL32 \
        -ltinyxml2 \
        -lfftw3
}

# The following keeps the generated files at least somewhat separate from the source files.
UI_DIR = uics
MOC_DIR = mocs
OBJECTS_DIR = objs