#
# qmake configuration for building with arm-linux-gnueabihf-g++ and mingw32-make
#

#MAKEFILE_GENERATOR      = MINGW
MAKEFILE_GENERATOR      = UNIX
CONFIG                 += incremental gdb_dwarf_index debug_and_release
QMAKE_INCREMENTAL_STYLE = sublib

include(../common/linux.conf)
include(../common/gcc-base-unix.conf)
include(../common/g++-unix.conf)

# modifications to g++.conf
QMAKE_CC                = arm-linux-gnueabihf-gcc
QMAKE_CXX               = arm-linux-gnueabihf-g++
QMAKE_LINK              = arm-linux-gnueabihf-g++
QMAKE_LINK_SHLIB        = arm-linux-gnueabihf-g++

# modifications to linux.conf
QMAKE_AR                = arm-linux-gnueabihf-ar cqs
QMAKE_OBJCOPY           = arm-linux-gnueabihf-objcopy
QMAKE_NM                = arm-linux-gnueabihf-nm -P
QMAKE_STRIP             = arm-linux-gnueabihf-strip

# modifications to compiler flags
COMPILER_ARM_FLAGS      = -march=armv7-a -mtune=cortex-a8 -mfpu=neon -mfloat-abi=hard
COMPILER_RELEASE_FLAGS  = -O3

QMAKE_CFLAGS           += $$COMPILER_ARM_FLAGS
QMAKE_CXXFLAGS         += $$COMPILER_ARM_FLAGS

QMAKE_CFLAGS_RELEASE    = $$COMPILER_RELEASE_FLAGS
QMAKE_CXXFLAGS_RELEASE  = $$COMPILER_ARM_FLAGS

# As we compile on windows, generate makefiles to use windows executables copy/xcopy/move/del/rmdir/mkdir
include(../common/shell-win32.conf)

load(qt_config)
