import QtQuick 2.8
import QtQuick.Window 2.2
import QtPositioning 5.9
import QtLocation 5.9

Window {
    visible: true
    width: 640
    height: 480
    title: qsTr("QML memory leak")

    property int itemCount: 300

    property var coords: ({})
    property var items: ({})

    property bool inBound: true

    Timer {
        id: timerPan
        running: false
        interval: 200;
        repeat: true;

        onTriggered: {
            if (inBound) {
                map.pan(width / 2, height / 2);
            } else {
                map.pan(-width / 2, -height / 2);
            }
            inBound = !inBound;
        }
    }

    Timer {
        id: timerItems
        running: false;
        interval: 100;
        repeat: true

        onTriggered: {
            var region = map.visibleRegion.boundingGeoRectangle();
            for(var i=0;i<itemCount;i++) {
                var index = "ct" + i;
                var coord = coords[index];
                var item = items[index];
                if (region.contains(coord)) {
                    if (item == undefined) {
                        item = itemDelegate.createObject(map, {index: i, coordinate: coord});
                        items[index] = item;

                    }
                    if (!item.onMap) {
                        map.addMapItem(item);
                        item.onMap = true;
                    }
                } else {
                    if (item) {
                        if (item.onMap) {
                            map.removeMapItem(item);
                            item.onMap = false;
                        }
                        item.destroy();
                        delete items[index];
                    }
                }
            }
        }
    }

    Map {
        id: map
        anchors.fill: parent

        plugin: Plugin {
            name: "itemsoverlay"
        }

        center {
            latitude: 0
            longitude: 0
        }

        zoomLevel: 18
    }

    Component.onCompleted: {
        for(var i=0;i<itemCount;i++) {
            var index = "ct" + i;
            coords[index] = QtPositioning.coordinate(
                        0 + (0.0001 * (i % 30)),
                        0 + (0.0001 * (i / 30)));
        }
        timerItems.start()
    }

    Component {
        id: itemDelegate

        MapQuickItem {
            id: quickItem
            property bool onMap: false
            property string imageLink: "image.png"
            property int index: 0

            sourceItem: Image {
                cache: false
                asynchronous: true
                source: onMap ? imageLink : ""
            }

            opacity: 1
            anchorPoint: Qt.point(0, sourceItem.height )
            zoomLevel: 20

            Component.onDestruction: {
                console.log("Destroying item#", index, "ImageStatus", sourceItem.status);
            }
        }
    }
}