Software Renderer: Updating a layer-enabled subtree while it is invisible produces wrong outcomes

// main.qml
import QtQuick 2.15
import QtQuick.Controls 2.15
import QtQuick.Layouts 1.15
import QtQuick.Shapes 1.15

ApplicationWindow
{
    id: root
    width: 640
    height: 480
    visible: true
    color: "black"

    property bool antialias: true // WORKAROUND: Make this `false`
    property int val: 0

    Item {
        id: gui
        anchors.fill: parent

        Column {
            anchors.fill: parent
            padding: 10
            spacing: 10
            Row {
                padding: 10
                spacing: 10

                Repeater {
                    model: 10

                    Shape {
                        // This is a simplified version of SvgPathItem from Qt Design Studio:
                        // https://code.qt.io/cgit/qt-labs/qtquickdesigner-components.git/tree/src/imports/components/SvgPathItem.qml?h=qds-4.2
                        id: shape
                        width: 50
                        height: 50

                        antialiasing: root.antialias
                        layer.enabled: root.antialias
                        layer.smooth: root.antialias
                        layer.samples: root.antialias ? 4 : 0

                        ShapePath {
                            strokeWidth: 0
                            strokeColor: "transparent"
                            fillColor: root.val > index ? "lime" : "grey"
                            PathSvg { path: "M 0 0 H 50 V 50 H 0 Z" }
                        }
                    }
                }
            }
            Text {
                text: `${root.val*10} %`
                color: "white"
            }
            Button {
                text: "Reset"
                onClicked: {
                    gui.visible = false // WORKAROUND: Comment out this line. Avoid changing values/colors while invisible
                    root.val = 0
                }
            }
        }
    }

    Timer {
        // Animate the progress bar
        interval: 200
        running: true
        repeat: true
        onTriggered: {
            ++root.val
            if (root.val > 10)
                root.val = 0
        }
    }
    Timer {
        // Un-hide the progress bar after a short delay
        interval: 100
        running: !gui.visible
        repeat: true
        onTriggered: gui.visible = true
    }
}