Make PathAttribute attributes compilable by qmlsc

import QtQuick

Window {
    width: 640
    height: 480
    visible: true

    PathView {
        anchors.fill: parent
        model: ListModel {
            ListElement {
                name: "Bill Jones"
                icon: "qtlogo.png"
            }
            ListElement {
                name: "Jane Doe"
                icon: "qtlogo.png"
            }
            ListElement {
                name: "John Smith"
                icon: "qtlogo.png"
            }
        }
        delegate: Item {
            id: element

            required property url icon
            required property string name

            width: 80
            height: 80
            scale: PathView.iconScale
            opacity: PathView.iconOpacity
            Column {
                Image {
                    anchors.horizontalCenter: nameText.horizontalCenter
                    width: 64
                    height: 64
                    source: element.icon
                }
                Text {
                    id: nameText
                    text: element.name
                    font.pointSize: 16
                }
            }
        }
        path: Path {
            startX: 120; startY: 100
            PathAttribute { name: "iconScale"; value: 1.0 }
            PathAttribute { name: "iconOpacity"; value: 1.0 }
            PathQuad { x: 120; y: 25; controlX: 260; controlY: 75 }
            PathAttribute { name: "iconScale"; value: 0.3 }
            PathAttribute { name: "iconOpacity"; value: 0.5 }
            PathQuad { x: 120; y: 100; controlX: -20; controlY: 75 }
        }
    }
}