Quick controls Popup - shadow is rendered incorrectly

import QtQuick
import QtQuick.Controls
import QtQuick.Effects

Window {
    width: 640
    height: 480
    visible: true
    color: "white"

    component Shadow : MultiEffect {
        shadowEnabled: true
        shadowColor: "black"
        shadowOpacity: 0.5
        shadowHorizontalOffset: 4
        shadowVerticalOffset: 5
    }

    component PopupFixedLayerEffect : Popup {
        id: control1

        background: Rectangle {
            radius: 10
            color: "white"

            layer.enabled: true
            layer.effect: Shadow {}
        }
    }

    component PopupDynamicLayerEffect : Popup {
        id: control2

        background: Rectangle {
            radius: 10
            color: "white"

            layer.enabled: control2.visible
            layer.effect: Shadow {}
        }
    }

    Rectangle { // Just for reference, how the shadow should look
        x: 20
        y: 20
        width: 200
        height: 200
        radius: 10

        layer.enabled: true
        layer.effect: Shadow {}
    }

    PopupFixedLayerEffect {
        id: p1;
        anchors.centerIn: parent

        Loader {
            active: p1.visible
            sourceComponent: Item {
                width: 200
                height: 200
            }
        }
    }
    PopupFixedLayerEffect {
        id: p2;
        anchors.centerIn: parent
        Loader {
            sourceComponent: Item {
                width: 200
                height: 200
            }
        }
    }
    PopupDynamicLayerEffect {
        id: p3
        anchors.centerIn: parent
        Loader {
            active: p3.visible
            sourceComponent: Item {
                width: 200
                height: 200
            }
        }
    }

    Column {
        spacing: 10
        anchors {
            right: parent.right
            top: parent.top
            rightMargin: 20
            topMargin: 20
        }

        Button {
            text: "Fixed layer.enabled, dynamic content"
            onClicked: p1.open()
        }
        Button {
            text: "Fixed layer.enabled, fixed content"
            onClicked: p2.open()
        }
        Button {
            text: "Dynamic layer.enabled,  dynamic content"
            onClicked: p3.open()
        }
    }
}