import QtQuick
import QtQuick.Controls.Basic
import QtGraphs

ApplicationWindow {
    id: root
    width: 800
    height: 600
    visibility: Window.FullScreen
    visible: true

    property int year: 2024

    header: Row {
        spacing: 10

        Button {
            text: "More Data"
            onClicked: {
                for (let i = 0; i < 5; ++i) {
                    dataModel.append({ year: root.year, city: "Oulu", expenses: 4000 })
                    dataModel.append({ year: root.year, city: "Helsinki", expenses: 8000 })
                    root.year += 1
                }
            }
        }
        Column {
            Label { text: "Zoom level: " + bars.cameraZoomLevel }
            Label { text: "Label count:" + bars.rowAxis.labels.length }
        }
        Slider {
            id: thicknessSlider
            from: 0.1
            value: 1
            to: 10
        }
        Switch {
            id: spacingRelativeSwitch
            text: "Spacing Relative"
        }
    }


    ListModel {
        id: dataModel
        ListElement{ year: 2022; city: "Oulu";     expenses: 4000; }
        ListElement{ year: 2022; city: "Helsinki"; expenses: 8000; }
        ListElement{ year: 2023; city: "Oulu";     expenses: 4000; }
        ListElement{ year: 2023; city: "Helsinki"; expenses: 8000; }
    }

    Bars3D {
        id: bars
        anchors.fill: parent
        barSpacingRelative: spacingRelativeSwitch.checked
        barThickness: thicknessSlider.value

        Bar3DSeries {
            itemLabelFormat: "@colLabel, @rowLabel: @valueLabel"

            ItemModelBarDataProxy {
                itemModel: dataModel
                columnRole: "city"
                rowRole: "year"
                valueRole: "expenses"
            }
        }
    }
}