import QtQuick 2.0
import QtWebSockets 1.0

Item {
  width: 360
  height: 360

  property url echoServer: 'ws://echo.websocket.org'
  property int concurrency: 5
  property int sizeStart: 1024 // 1 KiB
  property int sizeStop: 128 * 1024 // 128 KiB

  property int balance: 0
  property real lastTick: Date.now()
  property real startTime: Date.now()
  property int size: sizeStart

  WebSocket {
    id: socket
    url: echoServer
    active: true
    onTextMessageReceived: {
      log('Received message: ' + message.length)
      balance--
      var tick = Date.now()
      var delta = tick - lastTick
      if (delta > check.interval * 2)
        log('delta [missing]: ' + delta)
      if (balance === 0 && size > sizeStop)
        log('Total time: ' + (Date.now() - startTime) / 1000 + ' seconds')
    }
    onStatusChanged:
      if (socket.status == WebSocket.Error)
        log('Error: ' + socket.errorString)
      else if (socket.status == WebSocket.Open)
        log('Socket Opened')
      else if (socket.status == WebSocket.Closed)
        log('Socket closed')
  }
  Timer {
    id: check
    running: true
    interval: 10
    repeat: true
    onTriggered: {
      var tick = Date.now()
      var delta = tick - lastTick
      if (delta > interval * 2)
        log('delta: ' + delta)
      lastTick = tick
    }
  }
  Timer {
    running: socket.status === WebSocket.Open && balance == 0 && size <= sizeStop
    interval: 200
    repeat: true
    onTriggered: {
      for (var i = 0; i < concurrency; i++) {
        log('Sending message: ' + size)
        socket.sendTextMessage(new Array(size + 1).join('x'))
        balance++
      }
      size *= 2
    }
  }
  Text {
    id: messageBox
    anchors { bottom: parent.bottom; left: parent.left; right: parent.right }
  }
  function log(text) {
    console.log(text)
    messageBox.text += '\n' + text
  }
}