FocusReason is broken in Controls 2

import QtQuick 2.12
import QtQuick.Window 2.12
import QtQuick.Controls 2.12

Window {
    visible: true
    width: 640
    height: 480
    title: "Focus Reason Demo"

    Grid {
        columns: 2
        anchors.top: parent.top
        anchors.topMargin: 10
        anchors.horizontalCenter: parent.horizontalCenter
        spacing: 10

        Text {
            text: "Component"
            font.pixelSize: 16
        }

        Text {
            text: "Focus Reason"
            font.pixelSize: 16
        }

        ComboBox {
            editable: true
            model: ["Banana", "Apple", "Coconut", "Kiwi", "Mango #5", "Pomelo"]
            onEditTextChanged: console.log("onEditTextChanged: " + editText)
            onAccepted: console.log("onAccepted.\neditText: " + editText +"\ncurrentText: " + currentText + "\ncurrentIndex: " + currentIndex + "\n")

            onVisualFocusChanged: {
                console.log("ComboBox\n\tonVisualFocusChanged: " + visualFocus)
            }

            onActiveFocusChanged: {
                console.log("ComboBox\n\tonActiveFocusChanged: " + activeFocus +
                            "\n\tfocusReason: " + enumToString(focusReason))
                comboBoxReason.text = enumToString(focusReason)
            }

            contentItem.onActiveFocusChanged: {
                console.log("ComboBoxTextInput\n\tonActiveFocusChanged: " + activeFocus +
                            "\n\tfocusReason: " + enumToString(focusReason))
                comboBoxInputReason.text = enumToString(focusReason)
            }
        }

        Grid {
            columns: 2
            Text {
                text: "ComboBox: "
            }
            Text {
                id: comboBoxReason
                text: "None"
            }
            Text {
                text: "Input: "
            }
            Text {
                id: comboBoxInputReason
                text: "None"
            }
        }

        SpinBox {
            from: 0
            to: 100
            value: 20
            editable: true
            activeFocusOnTab: true

            onVisualFocusChanged: {
                console.log("SpinBox\n\tonVisualFocusChanged: " + visualFocus)
            }

            onActiveFocusChanged: {
                console.log("SpinBox\n\tonActiveFocusChanged: " + activeFocus +
                            "\n\tfocusReason: " + enumToString(focusReason))
                spinBoxReason.text = enumToString(focusReason)
            }

            contentItem.onActiveFocusChanged: {
                console.log("SpinBoxTextInput\n\tonActiveFocusChanged: " + activeFocus +
                            "\n\tfocusReason: " + enumToString(focusReason))
                spinBoxInputReason.text = enumToString(focusReason)
            }
        }

        Grid {
            columns: 2
            Text {
                text: "SpinBox: "
            }
            Text {
                id: spinBoxReason
                text: "None"
            }
            Text {
                text: "Input: "
            }
            Text {
                id: spinBoxInputReason
                text: "None"
            }
        }

        TextField {
            text: "test123"
            onActiveFocusChanged: {
                console.log("TextInput\n\tonActiveFocusChanged: " + activeFocus +
                            "\n\tfocusReason: " + enumToString(focusReason))
                textFieldReason.text = enumToString(focusReason)
            }
        }

        Text {
            id: textFieldReason
            text: "None"
        }
    }

    function enumToString(r)
    {
        switch (r) {
          case Qt.MouseFocusReason:
            return "Qt.MouseFocusReason";
          case Qt.TabFocusReason:
            return "Qt.TabFocusReason";
          case Qt.BacktabFocusReason:
            return "Qt.BacktabFocusReason";
          case Qt.ActiveWindowFocusReason:
            return "Qt.ActiveWindowFocusReason";
          case Qt.PopupFocusReason:
            return "Qt.PopupFocusReason";
          case Qt.ShortcutFocusReason:
            return "Qt.ShortcutFocusReason";
          case Qt.MenuBarFocusReason:
            return "Qt.MenuBarFocusReason";
          case Qt.OtherFocusReason:
            return "Qt.OtherFocusReason";
          default:
            return "UNKNOWN";
        }
    }
}