import QtQuick.Controls 2.4
import QtQuick 2.12

Rectangle {
    id: item

    property string display

    implicitWidth: 100
    implicitHeight: 100
    color: dropArea.containsDrag ? "#CFC" : "#EEE"

    ColorAnimation on color {
        id: rejectAnimation

        from: "#FCC"
        to: "#EEE"
        duration: 1000
    }
    Text {
        anchors.fill: parent
        text: item.display
        wrapMode: Text.WordWrap
    }
    DropArea {
        id: dropArea
        anchors.fill: parent
        keys: ["text/plain"]
        onDropped: if (drop.hasText) {
            if (drop.proposedAction == Qt.MoveAction || drop.proposedAction == Qt.CopyAction) {
                console.debug("DropArea onDropped", "proposed:", drop.proposedAction, "supported:", drop.supportedActions, "action:", drop.action)
                item.display = drop.text
                drop.acceptProposedAction()
            }
        }
    }
    MouseArea {
        id: mouseArea
        anchors.fill: parent
        drag.target: draggable
    }
    Item {
        id: draggable

        anchors.fill: parent
        Drag.active: mouseArea.drag.active
        Drag.hotSpot.x: 0
        Drag.hotSpot.y: 0
        Drag.mimeData: { "text/plain": item.display }
        Drag.dragType: Drag.Automatic
        Drag.proposedAction: Qt.CopyAction
        Drag.supportedActions: Qt.CopyAction | Qt.MoveAction
        Drag.onDragStarted: {
            console.debug("Drag.onDragStarted");
        }
        Drag.onDragFinished: {
            console.debug("Drag.onDragFinished dropAction:", dropAction)
            if (dropAction == Qt.MoveAction) item.display = ""
        }
    }
}