bool registerForIOSSwipes(QWidget* w, QSwipeGesture::SwipeDirection sd)
{
// cast the widget's winId (it's our ticket into the iOS underworld)
    auto uv = reinterpret_cast<UIView*>(w->winId());

// what we really like is a ptr to Qt's UIView (QUIView)
    if ("QUIView" != QString::fromNSString(NSStringFromClass([uv class])))
        return false;   // but it was not to be

// have a view, use a lambda to add the 4 different types of swipe gestures
    auto registerSwipe = [uv](UISwipeGestureRecognizerDirection d)
    {
    // new up an iOS gesture recognizer with required # of touches = 1 (Apple default)
        UISwipeGestureRecognizer* sgr = [[UISwipeGestureRecognizer alloc] initWithTarget:uv action:@selector(handleSwipe:)];
        [sgr setDirection:d];
        [uv addGestureRecognizer:sgr];
    };

    if (sd & QSwipeGesture::Left )
        registerSwipe(UISwipeGestureRecognizerDirectionLeft );

    if (sd & QSwipeGesture::Right)
        registerSwipe(UISwipeGestureRecognizerDirectionRight);

    if (sd & QSwipeGesture::Up   )
        registerSwipe(UISwipeGestureRecognizerDirectionUp   );

    if (sd & QSwipeGesture::Down )
        registerSwipe(UISwipeGestureRecognizerDirectionDown );

// that's all
    return true;
}

// some Objective-C red tape so we can inject our gesture recognizer function into Qt's QUIView
@interface QUIView : UIView @end    // (copied from quiview.h)

@implementation QUIView (RedTapeCategory) - (void) handleSwipe: (UISwipeGestureRecognizer*) swipe
{
// got a swipe, synthesize a swipe flavored Qt gesture event and post it
    auto sg = new QSwipeGesture;

    if (UISwipeGestureRecognizerDirectionLeft  == swipe.direction)
        sg->setSwipeAngle(180);

    if (UISwipeGestureRecognizerDirectionRight == swipe.direction)
        sg->setSwipeAngle(0);

    if (UISwipeGestureRecognizerDirectionUp    == swipe.direction)
        sg->setSwipeAngle(90);

    if (UISwipeGestureRecognizerDirectionDown  == swipe.direction)
        sg->setSwipeAngle(270);

    auto hotSpot = [swipe locationInView:self];
    sg->setHotSpot(QPointF(hotSpot.x,hotSpot.y));

// bon voyage
    qApp->postEvent(qApp->activeWindow(),new QGestureEvent(QList<QGesture*>{sg}));
}
@end

bool MainWindow::event(QEvent *event)
{
    if (event->type() != QEvent::Gesture)
        return QWidget::event(event);

    auto e = static_cast<QGestureEvent*>(event);
    auto g = e->gesture(Qt::SwipeGesture);
    if (nullptr == g)
        return QWidget::event(event);

    auto s = static_cast<QSwipeGesture*>(g);
    qDebug() << s->hotSpot() << s->horizontalDirection() << s->verticalDirection() << "Z";

    return true;
}