Tumbler is unable to rapidly snap to a new position

import QtQuick
import QtQuick.Controls.Basic

Window {
    id: root
    width: 640
    height: 480
    visible: true

    property int lastIndex: 4

    Row {
        anchors.fill: parent
        spacing: 10
        Column {
            Text { text: "ListView" }
            ListView {
                id: listView
                width: 100
                height: 200
                model: root.lastIndex + 1
                currentIndex: root.lastIndex
                clip: true
                delegate: Label {
                    required property int index
                    width: ListView.view.width
                    height: ListView.view.height
                    text: index
                    verticalAlignment: Qt.AlignVCenter
                }
            }
            Button {
                text: "Decrement"
                onClicked: listView.currentIndex--
            }
            Button {
                text: "Slow Reset"
                onClicked: listView.currentIndex = root.lastIndex
            }
            Button {
                text: "Fast Reset 1"
                onClicked: {
                    listView.currentIndex = root.lastIndex
                    listView.positionViewAtIndex(root.lastIndex, ListView.Beginning)
                }
            }
            Button {
                text: "Fast Reset 2"
                onClicked: {
                    listView.positionViewAtIndex(root.lastIndex, ListView.Beginning)
                    listView.currentIndex = root.lastIndex
                }
            }
        }
        Column {
            Text { text: "Tumbler" }
            Tumbler {
                id: tumbler
                model: root.lastIndex + 1
                currentIndex: root.lastIndex
                wrap: false
                visibleItemCount: 1
            }
            Button {
                text: "Decrement"
                onClicked: tumbler.currentIndex--
            }
            Button {
                text: "Slow Reset"
                onClicked: tumbler.currentIndex = root.lastIndex
            }
            Button {
                text: "Fast Reset 1"
                onClicked: {
                    tumbler.currentIndex = root.lastIndex
                    tumbler.positionViewAtIndex(root.lastIndex, Tumbler.Beginning)
                }
            }
            Button {
                text: "Fast Reset 2"
                onClicked: {
                    tumbler.positionViewAtIndex(root.lastIndex, Tumbler.Beginning)
                    tumbler.currentIndex = root.lastIndex
                }
            }
        }
    }
}